EFX-TEK Projects (Trade Show Displays) Video

[JonnyMac]

Our pal, Vern Graner, shot some video of our setup at the Maker Faire -- though he neglected to edit out my "I'm the best darned electronics guy you ever saw!" joke...

http://www.youtube.com/watch?v=7ncaX9QNSrI

[ilusion]

though he neglected to edit out my "I'm the best darned electronics guy you ever saw!" joke...

Well, it was an accurate quote... I mean, after all,  I didn't have a mirror handy...  ;D

Vern

[dacostasr]

Jon,

The prop I just bought the starter kit and RC-4 for is exactly like the Linda Blair in the video...is the code for that available?  I had  a pop-up TCT last year, but I've added a spitter, and want to add sound (haven't bought the board for that yet).

Ahhh, spiders preyground....one of my favorite videos to watch! Wondered if those kids ever stopped running!!?? LOL

Thanks,

Dennis

[JonnyMac]

Here you go... this should give you a couple ideas.

' =========================================================================
'
'   File....... BlairBarrel.BS1
'   Purpose.... Drive Linda Blair in a barrel pop-up prop
'   Author..... EFX-TEK
'   E-mail..... teamefx@efx-tek.com
'   Started....
'   Updated.... 02 JUL 2006
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------
'
' Control pop-up, lights, and sound for Pop Up Pazuzu prop.


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Sio             = 7                     ' remove ULN
SYMBOL  Spitter         = PIN1
SYMBOL  Head            = PIN0


' -----[ Constants ]-------------------------------------------------------

SYMBOL  Baud            = OT2400                ' B/R out
SYMBOL  Addr            = %11                   ' A0 and A1 in

SYMBOL  IsUp            = 1
SYMBOL  IsDown          = 0

SYMBOL  IsOn            = 1
SYMBOL  IsOff           = 0

SYMBOL  Dark            = %0000                 ' barrel lamps
SYMBOL  Yellow          = %0001
SYMBOL  Blue            = %0010
SYMBOL  Green           = %0100
SYMBOL  Red             = %1000
SYMBOL  Cyan            = %0110
SYMBOL  Purple          = %1010

SYMBOL  Scream          = 0
SYMBOL  Barf            = 1


' -----[ Variables ]-------------------------------------------------------

SYMBOL  color           = B2
SYMBOL  sfx             = B3
SYMBOL  idx             = B4
SYMBOL  showDelay       = W3
SYMBOL  lampDelay       = W4
SYMBOL  lottery         = W5


' -----[ Initialization ]--------------------------------------------------

Reset:
  DIRS = %00000011                              ' make valves outputs
  lottery = 1031                                ' seed the random value

  SEROUT Sio, OT2400, ("!!!!!!!AP8", %00, "X", "!RC4", %00, "X")


' -----[ Program Code ]----------------------------------------------------

Main:
  color = Cyan                                  ' warning color
  GOSUB Update_Lights
  PAUSE 1000
  Head = IsUp
  sfx = Scream
  GOSUB Play_Sound
  PAUSE 20
  color = Yellow
  GOSUB Update_Lights
  PAUSE 1800
  color = Purple
  GOSUB Update_Lights
  PAUSE 20
  sfx = Barf
  GOSUB Play_Sound
  PAUSE 200
  Spitter = IsOn
  PAUSE 1500
  Spitter = IsOff
  PAUSE 1000
  Head = IsDown

  color = Dark
  GOSUB Update_Lights
  PAUSE 5000

Bubble_Bubble:
  FOR showDelay = 1 TO 600
    FOR idx = 1 TO 3
      RANDOM lottery                            ' stir it up
    NEXT
    color = lottery                             ' randomize lamps
    GOSUB Update_Lights
    lampDelay = lottery & $03FF MIN 250         ' 0.25 to 1 sec
    PAUSE lampDelay
  NEXT

  GOTO Main


' -----[ Subroutines ]-----------------------------------------------------

Update_Lights:
  SEROUT Sio, OT2400, ("!RC4", %00, "S", color)
  RETURN

' -------------------------------------------------------------------------

Play_Sound:
  SEROUT Sio, OT2400, ("!AP8", %00, "P", sfx)
  RETURN


' -----[ EEPROM Data ]-----------------------------------------------------