Cratebeast finally finished

[ufo8mycow]

I finally got my cratebeast done with alot of help from Jon. It consists of a prop1, an ap8, two pneumatic cylinders with 12volt selonoids, 700 watt fogger modified with a 12volt relay inside and a red lightbulb. And if I can find one intime I will put a 12volt strobelight inside.

[ufo8mycow]

And here is the program.


' =========================================================================
'
'   File...... Crate_Beast_UFO8MyCow_v2.BS1
'   Purpose...
'   Author.... Jon Williams, EFX-TEK
'              Copyright (c) 2007 EFX-TEK
'   E-mail.... jwilliams@efx-tek.com
'   Started...
'   Updated... 19 OCT 2007
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Sio             = 7                     ' SETUP = out, no ULN
SYMBOL  PIR             = PIN6                  ' SETUP = DN
SYMBOL  Valve2          = PIN4                  ' OUT4/V+ to valve
SYMBOL  Valve1          = PIN3                  ' OUT3/V+ to valve
SYMBOL  Fogger          = PIN0                  ' OUT0/V+ to relay


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1                     ' for active-high in/out
SYMBOL  IsOff           = 0

SYMBOL  Baud            = OT2400


' -----[ Variables ]-------------------------------------------------------

SYMBOL  delay           = W3                    ' valve movement delay
SYMBOL  timer           = W4
SYMBOL  lottery         = W5                    ' random value
SYMBOL   lottoLo        = B10                   ' low byte of lottery
SYMBOL   lottoHi        = B11                   ' high byte of lottery


' -----[ Initialization ]--------------------------------------------------

Reset:
  PINS = %00000000                              ' all off
  DIRS = %00011111                              ' configure outputs

  SEROUT Sio, Baud, ("!!!!!!AP8", %00, "X")     ' stop audio if reset

  PAUSE 20000                                   ' warm-up/inter-show delay
  timer = 0                                     ' clear for PIR debounce


' -----[ Program Code ]----------------------------------------------------

Main:
  RANDOM lottery                                ' stir random value
  PAUSE 10
  timer = timer + 10 * PIR                      ' advance or clear timer
  IF timer < 250 THEN Main                      ' wait for valid signal

  Fogger = IsOn
  PAUSE 10

  SEROUT Sio, Baud, ("!AP8", %00, "P", 7)       ' start audio

  timer = 0                                     ' clear for jumping

Thrash_About:
  RANDOM lottery                                ' re-stir random value
  Valve1 = lottoLo                              ' valve1 = lottery.0
  Valve2 = lottoHi                              ' valve2 = lottery.8
  delay = lottery // 251 + 150                  ' 150 to 400 ms
  PAUSE delay
  timer = timer + delay
  IF timer < 8000 THEN Thrash_About

  GOTO Reset


' -----[ Subroutines ]-----------------------------------------------------


' -----[ User Data ]-------------------------------------------------------

[clinefx1]

Looks awesome and very clean.  How do you keep fog fluid from condensing and pooling at the bottom of your 2- 90 degree fittings?


-Chris

[ufo8mycow]

Looks awesome and very clean.  How do you keep fog fluid from condensing and pooling at the bottom of your 2- 90 degree fittings?


-Chris

I dont. It isnt sealed around the fogger so as you can kinda see in the pic it just drips out. any ideas?

[clinefx1]

you'll run into that pooling problem with every smoker. we usually drill a drain hole towards the bottom.  I have seen machines die because of fluid back up.