Prop 1 help

[darkride]

Ok so after tinkering with the prop1 all day using vixen i finally had thought i was in the clear zone- then something happened. So here's my show. A trunk lid pops up followed by a ghoul head that pops up a half second later and a scream. The head stays up for a total of 3 seconds, the lid four. It works beautifully when i first send power to the prop 1. After that  when the pri is triggered only the lid opens for about 12 seconds. The first show, the one i programmed only plays once at the beginning of power up, then never seen again. I must have done something wrong but i can not figure out where and how. I am determined to figure this out because i really like the support you get, the fair prices and the excallent cust service.

[JonnyMac]

Did you download the second set of Vixen fixes from today?  I found that I had left out a line of code that would prevent the sequence from working correctly the second time through.  We also found a bug in the add-in (though that wasn't affecting you); I just updated the files again about an hour ago (6:15 PM Pacific Time).

To be clear, the current Vixen add-ins for the Prop-1 and Prop-2 want to start the AP-8 at the beginning of the cycle -- this is because Vixen 1.11 does not allow you to move audio on the timeline, and until it does we're working with Vixen as is (future versions will allow you to start audio anywhere).

Your program description is quite simple -- this is what it would look like written manually (not audio starts as ghoul is emerging):

' =========================================================================
'
'   File...... Trunk_Ghoul.BS1
'   Purpose...
'   Author.... Jon Williams, EFX-TEK
'   E-mail.... jwilliams@efx-tek.com
'   Started...
'   Updated...
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Sio             = 7                     ' SETUP = out, no ULN
SYMBOL  PIR             = PIN6                  ' SETUP = DN
SYMBOL  Ghoul           = PIN1
SYMBOL  Trunk           = PIN0


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1
SYMBOL  IsOff           = 0

SYMBOL  IsOpen          = 1
SYMBOL  IsClosed        = 0

SYMBOL  IsUp            = 1
SYMBOL  IsDown          = 0

SYMBOL  Baud            = OT2400


' -----[ Variables ]-------------------------------------------------------

SYMBOL  pirTimer        = B2                    ' for debouncing


' -----[ Initialization ]--------------------------------------------------

Reset:
  PINS = %00000000                              ' clear everything
  DIRS = %00000011                              ' P0 and P1 are outputs

  SEROUT Sio, Baud, ("!!!!!!!AP8", %00, "X")    ' stop sound on manual reset

  PAUSE 20000                                   ' let PIR warm up
  pirTimer = 0                                  ' reset debounce timer


' -----[ Program Code ]----------------------------------------------------

Main:
  PAUSE 5
  pirTimer = pirTimer + 5 * PIR                 ' update debounce timer
  IF pirTimer < 250 THEN Main                   ' wait for valid signal

Show:
  Trunk = IsOpen                                ' pop the trunk!
  PAUSE 500

  SEROUT Sio, Baud, ("!AP8", %00, "P", 0)       ' scream

  Ghoul = IsUp
  PAUSE 3000

  Ghoul = IsDown
  PAUSE 500

  Trunk = IsClosed

  GOTO Reset


' -----[ Subroutines ]-----------------------------------------------------


' -----[ EEPROM Data ]-----------------------------------------------------

[darkride]

Thank you so much Jon. I actually pasted that code to my basic stamp, downloaded and played. And it played beautifully and perfectly everytime. Now i just need to learn how to write those type of codes on my own manually LoL. Is there any literature out thee that you could direct me to that could help me with this? I am actually doing a pro haunt next year and your products are exactly What i have been looking for. Thanks again
James

[JonnyMac]

Glad it worked for you.

Watch for my book, Prop-1 Programming: From Zero to Hero Without Breaking a Sweat or Bending Your Brain in early 2008.  Yes, I'm serious -- about the title, too.

[livinlowe]

Personally I LOVE the title!!!