Power - Volts & Amps - Prop 1

[WolfManor]

I am using the Prop 1 for the first time and have a question.

I have a Solenoid that uses 12vdc and 6 amps (As it is listed on the sticker).  Am I able to power that from the Prop 1?  I keep reading about 12vdc and 1 amp power supplies.  How would I go about doing that?

I have the code pretty good as I am a programmer in VB and this is very similar.  So far I have the following setup.

PIN7 = PIR
PIN0 = Solenoid

What else do I need to do?

Thanks,

Steve

Steve Bennett

[JonnyMac]

Six amps!  No -- it will come on for a moment and then then ULN will go up in smoke.   Now... look at the coil again.  Does it actually say "6 VA"?  If it does, that's a different story; that volt-amps (another term for DC watts) and that would be okay, but just barely, as it would be 500 mA and that is the single-channel limit of the ULN.  Relays are cheap and easy to come by, let me suggest that you find another -- like this one:

http://www.allelectronics.com/cgi-bin/item/4PRLY-12/search/RELAY,_4PDT_12VDC_KH_STYLE_.html

What do you want your program to do?  If you describe how you want the Solenoid to interact with the PIR I'll write a program for you.  PBASIC is different than VB (I use it, too), and one must be much more stingy with embedded resources, especially with a very small controller like the Prop-1.

[WolfManor]

Jon (Notice no "H"),

Thanks for the reply.  Here is what I know and have for info.

It is a NUMATICS Solenioid (Model 031SA441B000060) - It is a 12VDC Model.  They make this (MK3 Series) in several flavors.

According to the item I am holding in my hand it just says the following on the label "Numatics 236-102B, 12VDC, 6 Watts" but on the website and PDF info file (Link Included) it says the following:

Power (Watts) = 6
Holding Current (Amps) = 0.500
Inrush Current (Amps) = N/A

So based on what that says you are probably correct on the 500 mA.  Would you agree?  If that is correct, am I only able to power one solenoid with the Prop 1 or can it supply two or three?  Also, would I wire it to the PIN0 Post and not the V+?  What do you recommend for this?

Here is the link to the PDF file (Page 4 Has the "Operating Data" for the model).

  http://www.numatics.com/deliverables/catalogs/valves/mk3.pdf

I would love to see what you may be able to do for me in the coding department.  I figured you are pretty busy so I did not want to bother you with it.

Prop Details:
I am doing a simple popup for a head coming out of a cemetary column.  One cylinder.  Triggered by PIR.  I plan to leave it up for about 10 seconds and rest for 45 seconds between firings to give it some time to reset.  This is a prop that is on the corner of my cemetary fence and will be passed by many people walking near my yard.  I have about 3 feet from sidewalk to column for safety.

I am trying to understand the "Initializations" part.  I am understanding it as setting the pins for input and output.  So with that I assume that I could have 4 triggers if I set that those pins to Input "1" and then have the others as outputs by setting them to "0." Let me know if that is correct.  What I did below was copy one from a forum post and it seemed to work with the DEBUG calling out each operation.

' =========================================================================
'
'   File...... ColumnPopup.BS1
'   Purpose...
'   Author.... Steve
'   E-mail.... steveb@.....
'   Started... Sept. 8, 2007
'   Updated...
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================
' -----[ Program Description ]---------------------------------------------
' Simple Popup head out of column.

' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  PIR             = PIN7                  ' SETUP = DN
SYMBOL  Head            = PIN0


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1
SYMBOL  IsOff           = 0

SYMBOL  IsUp            = 1
SYMBOL  IsDown          = 0


' -----[ Variables ]-------------------------------------------------------


' -----[ Initialization ]--------------------------------------------------

Reset:
  DIRS = %00001111                              ' set output pins


' -----[ Program Code ]----------------------------------------------------

Main:
  IF PIR = IsOff THEN Main                  ' wait for trigger

  Head = IsUp
  PAUSE 10000                               'Pause with Head up for 10 seconds
  Head = IsDown
  PAUSE 45000                               'Reset for 45 Seconds

  GOTO Main


' -----[ Subroutines ]-----------------------------------------------------


' -------------------------------------------------------------------------


' -----[ EEPROM Data ]-----------------------------------------------------


I am looking to move into triggering sound, lights (110VAC) and fog as well.  I know this is a new topic so I do not want to get into it here , but would you have any suggestions on sound (About 30 seconds of sound) and getting a fogger to fill the column prior to opening?  Since I am new to all of your products, what can you tell me. 

If I need to post in another forum I can do that as well.

[JonnyMac]

Steve, 

Yes, I agree, that valve needs 0.5  amps and you can only run one at a time -- you might consider another valve.  We have lots of prop builders doing sophisticated (multi-valve) projects, perhaps one of them can suggest an alternative.  One possibility is going with their 24v valve as it only requires 0.25 amps.  The Prop-1 is designed to run at 24 volts as well, so this is okay.  That said, we don't offer a 24v power supply (Check with Evilusions or DC Prop Shop).

The DIRS = line in the initialization section sets inputs and outputs; a zero bit makes the pin an input, a one bit makes the pin an output.  In your case, with just one pin being an output you would have

DIRS = %00000001

This makes P0 an output, all the others inputs.  And no, you do not connect your valve to the P0 header; you connect it between OUT0 and V+ as shown in our documentation: http://www.efx-tek.com/downloads/prop-1_docs.pdf (see illustration on page 4).

Our AP-8 can handle 30 seconds of sound (up to 60, actually), and the RC-4 can switch AC lights and act as a remote fogger switch.  Both of these devices can be controlled from a singe I/O pin using serial communications

In the meantime I'd make a couple slight adjustments to your program:
-- move the PIR to P6 so that P7 is free for the AP-8 and RC-4 should you integrate them
-- debounce the PIR; these can be twitchy and debouncing ensures a valid signal.

If you decide you want to add sound, lights, and fogger control, tell me exactly how and when these things would interact with your prop and I'll insert them into the code.

' =========================================================================
'
'   File...... Column_Popup.BS1
'   Purpose...
'   Author.... Steve (with help from Jon Williams, EFX-TEK)
'   E-mail....
'   Started...
'   Updated...
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Sio             = 7                     ' SETUP = out; no ULN
SYMBOL  PIR             = PIN6                  ' SETUP = DN
SYMBOL  Head            = PIN0


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1                     ' for active-high in/out
SYMBOL  IsOff           = 0

SYMBOL  IsUp            = 1
SYMBOL  IsDown          = 0


' -----[ Variables ]-------------------------------------------------------

SYMBOL  pirTimer        = B2                    ' for PIR debouncing


' -----[ Initialization ]--------------------------------------------------

Reset:
  PINS = %00000000                              ' all clear
  DIRS = %00000001                              ' set output

  PAUSE 45000                                   ' PIR warm-up / delay
  pirTimer = 0                                  ' clear for next cycle


' -----[ Program Code ]----------------------------------------------------

Main:
  PAUSE 10
  pirTimer = pirTimer + 10 * PIR                ' update timer
  IF pirTimer < 250 THEN Main                   ' wait for valid signal

  Head = IsUp
  PAUSE 10000
  Head = IsDown

  GOTO Reset


' -----[ Subroutines ]-----------------------------------------------------


' -----[ User Data ]-------------------------------------------------------

[WolfManor]

Jon,

Thanks, I really do appreciate the help!  I will see what I can do for Solenoids.  I did look at Evilusions and will consider something from them.  I picked this solenoid up on Ebay for very little and was trying to make it work, but it may be a solution for a one cylinder prop and I will likely need to swap this out to get more fancy.

Thanks again your help! The info provided in these support forums is nothing less then the best!!

You have a customer/supporter for life!

Cheers,