Prop 1 controler and Fog Machine and Strobe Light

[Nick]

We have purchased a few of the Prop 1 controllers is there a way to make a Fog machine and strobe light work off the Prop 1 controller?

[livinlowe]

how are the Fog machine and Strobe light triggered? In my fog machine a switch closes and applies 120V ac to make fog. If this is the case you will need a RC-4 to make it work. Ditto for the Strobe light, the devil is in the details!

[JonnyMac]

Basically, you need a relay for each. 

WARNING: This stuff involves working with 120 VAC which can be dangerous -- even lethal -- if mishandled.  EFX-TEK provides this information as-is, with no warranty, and for information purposes only.  When working with 120 VAC circuits a qualified electrician should be employed.

You'll need one relay for each device; the relay should have a coil rating of 12v and no more than 3w. 

Fogger:

• Unplug it; unplug the remote cable from the fogger
• Open the fogger remote box. Connect one wire (#16 house wire) to each side of the remote's push-button.  Connect one of these wires to the COM terminal of the relay contracts, the other to the to the N.O. (normally open terminal).
• Connect the relay coil between V+ and the OUTx terminal of your choosing -- turn the output on to activate the fogger

Here's what the setup looks like, schematically:



Note that the fogger remote is just a N.O. push-button and we're adding another (albeit controllable) push-button (in the form of the relay contacts) across it.  If the button is pressed or the relay is on you will get fog.


Strobe:

• Get a 2-wire extension cord, split the wires at a convenient point, and then cut one
• Connect the cut wires to the COM and N.O. contacts on the relay
• Plug your strobe into the socket end of the extension cord

[livinlowe]

I see EFX-TEK is out of RC-4's, so here is an alternative:

http://www.hobbyengineering.com/H1243.html

[Nick]

So the bottom line is I need a R4 board to control the Light and Fog Machine, or can the Prop-1 Trigger some relays to do it if i follow the directions above.

[livinlowe]

You don't NEED a RC-4 board, it just is easier as you would have to solder if you go the relay's route that Jon showed. Seeing as their out of RC-4 boards right now I would say your decision is relays.

[BigRez]

Either way can do it for you: mechanical relays or RC-4.  I'm using both methods for some of my props.  A couple of things to note...

The RC-4 uses solid-state relays which are quiet.    The RC-4 can take 29 to 37ms to activate due to the serial IO and some other electrical conditions. The RC-4 takes one controller PIN connection (usually PIN7) and allows up to four RC-4 boards for a total of 16 devices using that single PIN.  The RC-4 is a nice, small package that makes the connections very easy and neat.

Mechanical relays click when activated.  This may not be an issue in a noisy environment, but if you activate the mechanical relays quickly, you could notice the clicking even when sounds are playing.  Each relay used would take a PIN assignment from the prop controller.  Connections can be easy if a relay board is used (see below) otherwise you'll be doing some soldering.

Here is a picture of each set up.  Note the relay board I have costs about $11 delivered.  (Search for "12v relay board" on ebay to see them in various configurations.)  I just swapped in the relay board to replace an RC-4 so I can use the RC-4 elsewhere, but because of the clicking on that prop, I'll probably put the RC-4 back in and just buy another.

[livinlowe]

Nice setup Bigrez!

[Nick]

Thank you so much for all the help so far on this prop.

I had Success at the Local electronics store and located some relays.

I have done very little programing of the Props we have. Most of it was written for us and we have modified it.

We are trying to develop a Electric Chair prop. I got the Program below from one of your Programs on these forums Jon. The chair works great the sound works awesome I have everything timed perfectly. My question is can you help me write in the program what would activate the Strobe relay and the Fog machine Relay? I have pasted the program below.




' =========================================================================
'
'   File......
'   Purpose...
'   Author....
'   E-mail....
'   Started...
'   Updated... 08 OCT 2009
'
' {$STAMP BS1}
' {$PBASIC 1.0}
'
' =========================================================================

' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Trigger         = PIN6                  ' SETUP = DN
SYMBOL  Thrasher        = 0
SYMBOL  CARP            = PIN5
SYMBOL  IsOff           = 0
SYMBOL  IsOn            = 1
SYMBOL  ThrashTime      = 20000                 ' 20 seconds

' -----[ Variables ]-------------------------------------------------------

SYMBOL  msDelay         = B2                    ' thrash cycle timing
SYMBOL  timer           = W4                    ' event timing
SYMBOL  lottery         = W5                    ' random value
' -----[ Initialization ]--------------------------------------------------

Reset:
  LOW Thrasher
' -----[ Program Code ]----------------------------------------------------

Main:
  IF Trigger = IsOff THEN Main                  ' wait for trigger
    timer = 0                                   ' reset timer

  Start_Audio:
  CARP = IsOn                                   ' pulse to start CAR/P-300
  PAUSE 100
  CARP = IsOff
  PAUSE 22000                                   ' audio run time (20 secs)

  Thrash_Baby_Thrash:
  IF timer > ThrashTime THEN Settle_Down        ' quit if timer expired
    RANDOM lottery                              ' create new timing
    msDelay = lottery // 201 + 50               ' between 50 and 250 ms
    TOGGLE Thrasher                             ' flip cylinder status
    PAUSE msDelay                               ' hold
    timer = timer + msDelay                     ' update timer
    GOTO Thrash_Baby_Thrash

Settle_Down:
  LOW Thrasher                                  ' stop it!
  PAUSE 15000                                   ' hold 15 secs
  GOTO Main                                     ' start over


' -----[ Subroutines ]-----------------------------------------------------

[JonnyMac]

I can help you when you give me specifics....

1) When does the strobe come on and for how long does it run?
2) When does the fogger come on and for how long does it run?

I'm pretty good at programming, but skipped class when mind-reading was covered!  ;D

[Nick]

Sorry I knew I missed something in the last post.

I would like the Light and Fog Machine to come on Right before the Thrasher Program Starts.

I want it to play the music which is 20 secs. then he starts his dance in the chair. Right before he starts moving I would like the strobe to come on and the fog machine to come on 2-5 second later I would like them both to run the duration of the Thrashing then reset and be ready for the next Trigger.

Thanks Again Jon

[JonnyMac]

Here you go.  The fogger starts three seconds into the cycle and runs two seconds -- that should be enough to get a big puff of smoke out.

' =========================================================================
'
'   File......
'   Purpose...
'   Author....
'   E-mail....
'   Started...
'   Updated... 10 OCT 2009
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Trigger         = PIN6                  ' SETUP = DN
SYMBOL  CARP            = PIN5

SYMBOL  Fogger          = PIN2
SYMBOL  Strobe          = PIN1
SYMBOL  Thrasher        = PIN0


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1                     ' for active-high in/out
SYMBOL  IsOff           = 0

SYMBOL  Yes             = 1
SYMBOL  No              = 0

SYMBOL  ThrashTime      = 20000                 ' 20 seconds


' -----[ Variables ]-------------------------------------------------------

SYMBOL  delay           = W3                    ' thrash cycle timing
SYMBOL  timer           = W4                    ' event timing
SYMBOL  lottery         = W5                    ' random value


' -----[ Initialization ]--------------------------------------------------

Reset:
  PINS = %00000000                              ' clear all
  DIRS = %00000111                              ' set output pins

  PAUSE 15000                                   ' reset delay


' -----[ Program Code ]----------------------------------------------------

Main:
  timer = 0                                     ' reset timer

Check_Trigger:
  PAUSE 5                                       ' loop pad
  timer = timer + 5 * Trigger                   ' update timer
  IF timer < 100 THEN Check_Trigger             ' wait for 0.1 sec input

Start_Audio:
  CARP = IsOn                                   ' pulse to start CAR/P-300
  PAUSE 100
  CARP = IsOff
  PAUSE 22000                                   ' audio run time (20 secs)

  timer = 0                                     ' reset timer
  Strobe = IsOn

Thrash_Baby:
  RANDOM lottery
  delay = lottery // 201 + 50                   ' between 50 and 250 ms
  Thrasher = 1 - Thrasher                       ' flip cylinder status
  PAUSE delay                                   ' hold
  timer = timer + delay                         ' update timer

Check_Fog_Start:
  IF timer < 3000 THEN Thrash_Baby              ' time to start fogger?
    Fogger = IsOn                               ' yes

Check_Fog_End:
  IF timer < 5000 THEN Thrash_Baby              ' time to stop fogger?
    Fogger = IsOff                              ' yes

Check_Thrash_End:
  IF timer < ThrashTime THEN Thrash_Baby        ' done?
    GOTO Reset                                  ' yes, clear everthing


' -----[ Subroutines ]-----------------------------------------------------