Buzzy Bee Redemption Game--Prop-1 version

[jukingeo]

Hello all.

I initially started this post back in the Prop-2 message board as I started this program out there.  However, it WAS initially intended for the Prop-1.  In the meantime I finally purchased a Prop-1 for myself and converted the program over from the Prop-2 version I created here:

http://www.efx-tek.com/php/smf/index.php?topic=1395.0

You may follow the thread down and you will see that I started to divert the topic to the Prop-1 (My bad, Sorry!).  So I decided to fix things up and put the discussion and put it in it's proper place.

Ok, moving on basically the program below was created after I witnessed a particular redemption game in operation.  The game is called Buzzy Buzzy Bee and it looks like this:

http://www.arcadeflyers.com/?page=flyer&db=arcadedb&id=1179&image=1

In a nutshell, you put a coin in the game and music starts to play as a blower fan starts up and circulates ping pong balls in a tank (much like the money machine).  The balls are painted with black and yellow strips to simulate 'bees'.  There is a funnel type 'catcher's net' that you can move it in all directions via a universal joint that has the net's handle extend out of the cabinet.   the goal is to 'catch' a bee and put it in a 'honey pot' mounted on the left rear side of the enclosure.  Each time a 'bee' is placed in a pot, a sound is made and the score counter is incremented.  The game continues until a timer shuts off the fan and the music.  Then tickets are paid out based on how high the score is.

The game cabinet does have flashing lights on it that are activated during play and also via an attract mode.

After watching/playing the game several times, I realized that this could be something that can be made utilizing a Prop-1 controller, an AP-8 and an RC-4.   Given that I don't own a Prop-1 but a Prop-2 instead, I decided to sit down and tackle the code for this game.

Now I have not tested it as of yet as I have my controllers put away, but I am going to go through my boxes and dig them out this weekend.  I figured I would post the code here in case someone might have suggestions and/or corrections as I am SURE I made some errors here.

While I have fixed most of the errors, I discovered a new problem, I need a two switch input AND a Serial link for the RC-4 and AP-8.  The presence of these does render using the Prop-1 trainer out of the question.  So I cannot get visual feedback on the output lines on the Prop-1 itself.   So I have not tested the code below.

What I might do, since I have a second RC-4 is to temporarily set that one up on the Sio line so I can verify that the 4 outputs are indeed properly operating as intended.

The original game had two score boards, one for the actual score and one for time remaining.  I found that when playing the game, I very rarely look at either.  Observing kids playing the game, I noticed the same thing.   So I decided to drop the count down timer display.   I also used up all the variables with this program as it is.

Now naturally if anyone would like to improve on the program, by all means I am all ears (eyes really).

What I am basically going to do on subsequent trips to Chuck E. Cheese is to note the operation of other redemption games.

Those with good cabinet makings skills, teaming up with the supplies at www.happcontrols.com could make their own 'home' versions of many of the games.   I chose the Buzzy Buzzy Bee game first because it seemed like the easiest one to construct from a mechanical point of view.   There WERE simpler games I have seen and they could be easily programmed by the Prop-1, but they have really weird custom parts....so I am going to avoid those for now.

Anyway here is the (updated) code if you want to try it out.

Code Select Expand

Code:

' =========================================================================

'

'   File...... Buzzy Bee Redemption Game.BS1

'   Purpose...

'   Author.... Geo M

'   E-mail....

'   Started...

'   Updated...

'

'   {$STAMP BS1}

'   {$PBASIC 1.0}

'

' =========================================================================





' -----[ Program Description ]---------------------------------------------

' This program mimics the operation of the Buzzy Buzzy Bee redemption game.

' The Buzzy Bee game centers around catching ping pong balls that are circ-

' ulated around an enclosed tank via a fan. The ping pong balls are striped

' yellow and black to mimic 'bees'.  You catch the floating bees using a

' plastic 'net' on a long shaft that is connected via a universial joint like

' mount that has a handle on the outside of the cabinet.  The caught 'bees'

' are placed in a honey jar container that is on the left side of the play

' area.  The score is incremented for each 'bee' caught.

'

' The game is run on a timed basis which starts after a coin is inserted.

' Music plays in the background as the game is in progress. When the time

' is complete the fan shuts off, the lights turn off, and the music stops.

' Finally a ticket dispenser pays out a number of tickets based ON the

' final score. The game then enters an 'attract' mode awaiting another coin.

'

' Note: The light flash pattern is different for attract v.s. game play.



' -----[ Revision History ]------------------------------------------------





' -----[ I/O Definitions ]-------------------------------------------------



SYMBOL  Sio          = PIN7                      ' for AP-8, no ULN or SETUP

SYMBOL  TriggerC     = PIN6                      ' SETUP = DN-Coin Slot

SYMBOL  TriggerB     = PIN5                      ' SETUP = DN-Score Increment



SYMBOL  ScoreInc     = PIN3                      ' Scoreboard increment pulse

SYMBOL  Ticket       = PIN2                      ' Ticket Dispenser

SYMBOL  CoinIns      = PIN1                      ' Insert Coin LED (lamp)

SYMBOL  ScoreClr     = PIN0                      ' Clears Scoreboard



' -----[ Constants ]-------------------------------------------------------



SYMBOL  IsOn            = 1

SYMBOL  IsOff           = 0



SYMBOL  TimerMult       = 6                      ' game timer multiplier 1-6

                                                 ' 1 = 10sec, 2 = 20, etc

SYMBOL  TickInc         = 5                      ' Ticket point award. E.G if

                                                 ' set to 5, a ticket will be

                                                 ' awarded for every 5 points

SYMBOL  Baud            = OT2400



'T2400           CON     396

'T38K4           CON     6

'Open            CON     $8000



'Baud            CON     Open | T38K4





' -----[ Variables ]-------------------------------------------------------



SYMBOL  timer           = W1

SYMBOL  timerloop       = W2



SYMBOL  music           = B6                     ' Set AP-8 to Loop Mode

SYMBOL  chase           = B7

SYMBOL  score           = B8

SYMBOL  tickout         = B9





SYMBOL  relays          = B0                     ' Relay outputs

Cablmp1        VAR     relays.BIT0              ' RC-4.K0

Cablmp2        VAR     relays.BIT1              ' RC-4.K1

Cablmp3        VAR     relays.BIT2              ' RC-4.K2

Fan            VAR     relays.BIT3              ' RC-4.K3



' -----[ Initialization ]--------------------------------------------------



Reset:

  SEROUT Sio, Baud, ["!!!!!!!!AP8", %00, "X", "!RC4", %00, "X"]



  PINS = %00000000

  DIRS = %00011111



  timer = (100 * TimerMult)                   'Timer multiplier

  chase = 0                                     'Set lamp chase start at 0

  score = 0



  GOSUB All_Off





' -----[ Program Code ]----------------------------------------------------



Main:

  CoinIns = IsOn                                ' Turn on Coin Insert Lamp



Attract:

  IF (TriggerC = IsOn) THEN Run_Game            ' while waiting for coin



  chase = chase + 1 // 5                        ' Update cabinet light chase

    LOOKUP chase, [%001, %011, %111, %110, %100], relays

    GOSUB Update_RC4

  GOTO Attract



Run_Game:

  CoinIns = IsOff                               ' Turn off Coin Insert Lamp

  PULSOUT ScoreClr, 50                          ' Clears Scoreboard

  chase = 0                                     ' resets chase lights



  music = 0                                     ' Plays Music Clip at "0"

  GOSUB Play_AP8



  Fan = IsOn                                    ' Turn On Fan

  GOSUB Update_RC4



  FOR timerloop = timer TO 0 STEP - 1           ' Main timer loop

    IF (TriggerB = IsOn) THEN GOSUB Score_Keep  ' Update score

    chase = chase + 1 // 3                      ' Update cabinet light chase

    LOOKUP chase, [%110, %101, %011], relays

    GOSUB Update_RC4

    PAUSE 100

  NEXT



  Fan = IsOff                                   ' Turn Off Fan



  GOSUB Stop_AP8



  Music = 7                                     ' Change To Chime



  GOSUB Play_AP8                                ' Play chime as ticket pays out

  FOR tickout= score TO 0 STEP - TickInc        ' Ticket Payout

    PULSOUT Ticket, 50

    PAUSE 1000

  NEXT

  GOSUB Stop_AP8                                ' Shut down audio



GOTO Main                                      ' Rinse & Repeat





' -----[ Subroutines ]-----------------------------------------------------



Play_AP8:

  SEROUT Sio, Baud, ["!AP8", %00, "P", music]

  RETURN





Stop_AP8:

  SEROUT Sio, Baud, ["!AP8", %00, "X"]

  RETURN





' -------------------------------------------------------------------------



Update_RC4:

  SEROUT Sio, Baud, ["!RC4", %00, "S", relays]

  RETURN



' -------------------------------------------------------------------------



All_Off:

  OUTS = $0000

  relays = %0000

  GOSUB Update_RC4

  RETURN



'--------------------------------------------------------------------------



Score_Keep:                            ' Update Score routine



  PULSOUT ScoreInc, 50

  score = score + 1

  RETURN





' -----[ EEPROM Data ]--------------------------------------------------

[bsnut]

Geo,

You need to test the program I wrote for you. Because, you are still thinking in the BS2(Prop2) mindset with the program you wrote here. Here's some of your problems.

1) You only need one serial I/O when using RC4 and the AP8. This means, you can daisy chain your serial. You take one end of the servo cable and connect it to your Prop1 pin header. Then take the other end of that servo cable to the RC4 and the second servo cable and connect it to the RC4 and from the RC4 to the AP8.

2) Look at my program that I wrote and you will see that I didn't used PIN for the outputs like CoinIns.  This, is the way it should look:
SYMBOL  CoinIns      = 1

Not like this, because the PBASIC1 (Prop1) doesn't use the PIN directive for the doing the outputs:
SYMBOL  CoinIns      = PIN1

It won't work on Prop1 (Basic1)

3) Now, lets look at my program that I wrote and you can see how I turn your fan motor off on the RC4 under the "Attract" Label, it needs to look like this:
LOOKUP chase, (%0010, %0110, %1110, %1100, %1000), relays  

Not like this:
LOOKUP chase, [%001, %011, %111, %110, %100], relays

And here's why. The RC4 syntax is this SEROUT Sio, OT2400, ("!RC4", %00, "S", relays), which means relay K1, K3, and K4 will be deactivated, while K2 will be activated at beginning of the LOOKUP syntax. Your syntax will turn your fan motor on, because of the execution speed of Basic Stamp1 processor and second problem is that you left out the PAUSE command out of the FOR/NEXT part of the program and the third problem is, that you use brackets for your indexed data. Brackets are not allow for the PBasic1.  Now if you had, put in PAUSE 250 command in your program, it will turn on the fan motor for the first three indexes of the LOOKUP chase, and turn off the fan motor for the last two indexes of the LOOKUP chase. This will be giving you unpredictable results on the RC4 outputs.

Now here's how I to turn your fan motor on under the "Run_Game Label":
LOOKUP chase, (%1101, %1011, %0111), relays

As you can see, relays K1, K3, and K4 are activated and relay K2 is deactivated.By, doing this way you prevent unpredictable results to the RC4 and you are able to turn on and off the "fan motor" on the RC4 the way you want without unwanted results.

4)The other problem with your program is this, it wasn't  define at the beginning of your program and this syntax will not compile when try to download it and you will get an syntax error:  
Fan = IsOff                                   ' Turn Off Fan

You should have define it like this:
SYMBOL  Fan     = 4                      ' Fan motor

Now, this syntax will work:
Fan = IsOff                                   ' Turn Off Fan

Now the the whole program should work with no problems.

If, I was you, I would controlled the "fan motor" as an output on the Prop1 pin(OUTx) with a relay and not from the RC4 this way you will not get unpredictable results when chasing the lights. By doing this, you get one extra relay for cabinet lights.

When I write programs for automated equipment that I work on or need to modify, this includes PLC's and Microcontrollers, I keep it simple ;D. Remember you are always learning new ways to write your programs and always use that help file.

[jukingeo]

Hello bsnut.   I moved your program here so I can do the comparison and being that it is anyway Prop-1 relevant it belongs here.

Code Select Expand

'   File.......Prop1 Buzzy Bee Redemption Game
'   Author.....W. Stefan
'   E-mail.....
'   Started....
'   Updated....
' {$STAMP BS1}
' {$PBASIC 1.0}
' -----[ Program Description ]---------------------------------------------

' This program mimics the operation of the Buzzy Buzzy Bee redemption game.
' The Buzzy Bee game centers around catching ping pong balls that are circ-
' ulated around an enclosed tank via a fan. The ping pong balls are striped
' yellow and black to mimic 'bees'.  You catch the floating bees using a
' plastic 'net' on a long shaft that is connected via a universial joint like
' mount that has a handle on the outside of the cabinet.  The caught 'bees'
' are placed in a honey jar container that is on the left side of the play
' area.  The score is incremented for each 'bee' caught.
'
' The game is run on a timed basis which starts after a coin is inserted.
' Music plays in the background as the game is in progress. When the time
' is complete the fan shuts off, the lights turn off, and the music stops.
' Finally a ticket dispenser pays out a number of tickets based ON the
' final score. The game then enters an 'attract' mode awaiting another coin.

'

' Note: The light flash pattern is different for attract v.s. game play.

' RC4 relay bit patterns for SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
' relays = K4:Cabinet Lamp1, K3:Cabinet Lamp2, K2:Cabinet Lamp3, K1:Fan Motor
'           |                 |                 |                 |
'  +--------+                 |                 |                 |
'  |+-------------------------+                 |                 |
'  ||+------------------------------------------+                 |
'  |||+-----------------------------------------------------------+
' %1001 This is relay pattern used in the LOOKUP Command
'INPUTS
'--------------------------------------------------------------------
SYMBOL TriggerB = PIN0       ' Score Increment
SYMBOL TriggerC = PIN1       ' Coin Slot


'OUTPUTS
'--------------------------------------------------------------------
SYMBOL CoinIns  = 2          ' Insert Coin LED (lamp) OUT2 - +V
SYMBOL ScoreInc = 3          ' Scoreboard increment pulse OUT3 - +V
SYMBOL Ticket   = 4          ' Ticket Dispenser OUT4 - +V

'RC-4/AP-8 SERIAL I/O
'--------------------------------------------------------------------
SYMBOL Sio     = 7               ' no ULN or SETUP

'CONSTANTS
'--------------------------------------------------------------------
SYMBOL TickInc = 5           ' Ticket point award.

'VARIABLES
'--------------------------------------------------------------------
SYMBOL timer   = W0
SYMBOL score   = B2
SYMBOL chase   = B3            'LOOKUP Pointer
SYMBOL relays  = B4
SYMBOL tickout = B5
SYMBOL Baud    = OT2400
SYMBOL Addr    = %00

'EEPROM DATA
'--------------------------------------------------------------------

'INITIALIZATION
'--------------------------------------------------------------------
Reset:
SEROUT Sio, Baud, ("!RC4", %00, "x")
SEROUT Sio, Baud, ("!AP8", %00, "x")
score = 0
timer = 0

'PROGRAM CODE
'--------------------------------------------------------------------
Main:
  GOSUB Attract_Update_RC4
  PAUSE 250
  IF TriggerC = 1 THEN Start_Game_Music
  GOTO Main

Start_Game_Music:
  SEROUT Sio, Baud, ("!AP8", %00, "P", 0) '

Run_Game:
  IF timer = 480 THEN Ticket_Payout
  GOSUB Run_Game_Update_RC4
  PAUSE 250
  timer = timer +1
  IF TriggerB = 1 THEN Score_Keep
  GOTO Run_Game

Score_Keep:
  PULSOUT ScoreInc, 50
  score = score + 1
  DEBUG score, CR
  GOSUB Run_Game_Update_RC4
  PAUSE 250
  timer = timer +1
  GOTO Run_Game

Ticket_Payout:
  SEROUT Sio, Baud, ("!AP8", %00, "P", 7) ' Play chime as ticket pays out
  FOR tickout = score TO 0                ' Ticket Payout
    PULSOUT Ticket, 50
    PAUSE 1000
  NEXT
  GOTO Reset

'SUBROUTINES
'--------------------------------------------------------------------
Attract_Update_RC4:
chase = chase + 1 // 5                       ' Update cabinet light chase
  LOOKUP chase, (%0010, %0110, %1110, %1100, %1000), relays
  SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
  RETURN

Run_Game_Update_RC4:
chase = chase + 1 // 3                      ' Update cabinet light chase
  LOOKUP chase, (%1101, %1011, %0111), relays
  SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
  RETURN

[bsnut]

Geo,

I will post the update code listing. Here's why. There is minor problems with Ticket_Payout Label. My bad. This is what it needs to be.
Ticket_Payout:
SEROUT Sio, Baud ("!AP8", %00, "P", 7)
FOR tickout = 0 TO score    'Ticket Payout
PULSOUT Ticket, 50
PAUSE 1000
DEBUG score, CR
NEXT
GOTO Reset

The FOR/NEXT had be switched around, because I made minor typeo,my bad.

I will carry over my later posting from Prop2 thread too.

[jukingeo]

Hello Bsnut,

A couple posts back you mentioned that you 'checked' the program and how much memory it takes.  May I ask how you did that?  I came across another program that I wanted to convert from the Prop-2 and it looks kind of long.

The original program is here:

http://www.efx-tek.com/php/smf/index.php?topic=242.msg1330#msg1330

But I would like to know how to check a program considering that the Prop-1 is considerably more limited in memory capacity than the Prop-2.

Thanx,

Geo

[bsnut]

Geo,

Yes you may. In the Parallax Stamp Editor has two ways of doing this

1) Click on Run> Then Memory Map.
2) Or click on the icon, which is on the left side of the Run icon

This is what Memory Map does when you have done one of the things above

1) It checks the syntax (looking errors  in your program) then it compiles the program
2) If their no errors in your program, then Stamp Editor will display a graph showing you the % of EEPROM used. It also displaying how the Basic Stamp used "Words" (W0), "Bytes" (B0), and GOSUB's in your program. This can help you in many ways, like checking for overlapping bytes and words or if your program is full (100%) and you are trying to get little more out of your EEPROM, it can give you a hint that you need to trim down your program in order to get more in the EEPROM. Remember every Basic Stamp command uses different % of the EEPROM when your program is compiled.

I hope I answer your question. I am starting to feel like JonnyMac ;D.    

[bsnut]

Here's your program I did. It is 69% full and missing some of the features that your program had. I can put them in if you want. Please test this one so you can see how it works.

Code Select Expand

'   File.......Prop1 Buzzy Bee Redemption Game
'   Author.....W. Stefan
'   E-mail.....
'   Started....
'   Updated....
' {$STAMP BS1}
' {$PBASIC 1.0}
' -----[ Program Description ]---------------------------------------------

' This program mimics the operation of the Buzzy Buzzy Bee redemption game.
' The Buzzy Bee game centers around catching ping pong balls that are circ-
' ulated around an enclosed tank via a fan. The ping pong balls are striped
' yellow and black to mimic 'bees'.  You catch the floating bees using a
' plastic 'net' on a long shaft that is connected via a universial joint like
' mount that has a handle on the outside of the cabinet.  The caught 'bees'
' are placed in a honey jar container that is on the left side of the play
' area.  The score is incremented for each 'bee' caught.
'
' The game is run on a timed basis which starts after a coin is inserted.
' Music plays in the background as the game is in progress. When the time
' is complete the fan shuts off, the lights turn off, and the music stops.
' Finally a ticket dispenser pays out a number of tickets based ON the
' final score. The game then enters an 'attract' mode awaiting another coin.

'

' Note: The light flash pattern is different for attract v.s. game play.

' RC4 relay bit patterns for SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
' relays = K4:Cabinet Lamp1, K3:Cabinet Lamp2, K2:Cabinet Lamp3, K1:Fan Motor
'           |                 |                 |                 |
'  +--------+                 |                 |                 |
'  |+-------------------------+                 |                 |
'  ||+------------------------------------------+                 |
'  |||+-----------------------------------------------------------+
' %1001 This is relay pattern used in the LOOKUP Command
'INPUTS
'--------------------------------------------------------------------
SYMBOL TriggerB = PIN0       ' Score Increment
SYMBOL TriggerC = PIN1       ' Coin Slot


'OUTPUTS
'--------------------------------------------------------------------
SYMBOL CoinIns  = 2          ' Insert Coin LED (lamp) OUT2 - +V
SYMBOL ScoreInc = 3          ' Scoreboard increment pulse OUT3 - +V
SYMBOL Ticket   = 4          ' Ticket Dispenser OUT4 - +V

'RC-4/AP-8 SERIAL I/O
'--------------------------------------------------------------------
SYMBOL Sio     = 7               ' no ULN or SETUP

'CONSTANTS
'--------------------------------------------------------------------
SYMBOL TickInc = 5           ' Ticket point award.

'VARIABLES
'--------------------------------------------------------------------
SYMBOL timer   = W0
SYMBOL score   = B2
SYMBOL chase   = B3            'LOOKUP Pointer
SYMBOL relays  = B4
SYMBOL tickout = B5
SYMBOL Baud    = OT2400
SYMBOL Addr    = %00

'EEPROM DATA
'--------------------------------------------------------------------

'INITIALIZATION
'--------------------------------------------------------------------
Reset:
SEROUT Sio, Baud, ("!RC4", %00, "x")
SEROUT Sio, Baud, ("!AP8", %00, "x")
score = 0
timer = 0

'PROGRAM CODE
'--------------------------------------------------------------------
Main:
 GOSUB Attract_Update_RC4
 PAUSE 250
 IF TriggerC = 1 THEN Start_Game_Music
 GOTO Main

Start_Game_Music:
 SEROUT Sio, Baud, ("!AP8", %00, "P", 0) '

Run_Game:
 IF timer = 480 THEN Ticket_Payout
 GOSUB Run_Game_Update_RC4
 PAUSE 250
 timer = timer +1
 IF TriggerB = 1 THEN Score_Keep
 GOTO Run_Game

Score_Keep:
 PULSOUT ScoreInc, 50
 score = score + 1
 DEBUG score, CR
 GOSUB Run_Game_Update_RC4
 PAUSE 250
 timer = timer +1
 GOTO Run_Game

Ticket_Payout:
 SEROUT Sio, Baud, ("!AP8", %00, "x")
 SEROUT Sio, Baud, ("!AP8", %00, "P", 7) ' Play chime as ticket pays out
 FOR tickout = 0 TO score                ' Ticket Payout
   PULSOUT Ticket, 50
   DEBUG tickout, CR
   PAUSE 1000
 NEXT
 GOTO Reset

'SUBROUTINES
'--------------------------------------------------------------------
Attract_Update_RC4:
chase = chase + 1 // 5                       ' Update cabinet light chase
 LOOKUP chase, (%0010, %0110, %1110, %1100, %1000), relays
 SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
 RETURN

Run_Game_Update_RC4:
chase = chase + 1 // 3                      ' Update cabinet light chase
 LOOKUP chase, (%1101, %1011, %0111), relays
 SEROUT Sio, Baud, ("!RC4", %00, "S", relays)
 RETURN

[jukingeo]

Geo,

Yes you may. In the Parallax Stamp Editor has two ways of doing this

1) Click on Run> Then Memory Map.
2) Or click on the icon, which is on the left side of the Run icon

Oh, man!  A thing of beauty!

This is what Memory Map does when you have done one of the things above

1) It checks the syntax (looking errors  in your program) then it compiles the program
2) If their no errors in your program, then Stamp Editor will display a graph showing you the % of EEPROM used. It also displaying how the Basic Stamp used "Words" (W0), "Bytes" (B0), and GOSUB's in your program. This can help you in many ways, like checking for overlapping bytes and words or if your program is full (100%) and you are trying to get little more out of your EEPROM, it can give you a hint that you need to trim down your program in order to get more in the EEPROM. Remember every Basic Stamp command uses different % of the EEPROM when your program is compiled.

I hope I answer your question. I am starting to feel like JonnyMac ;D.    

Definitely!  I am sure this works for the BS-2 as well, correct?  However, I never felt likely to run out of memory any time soon with that one.  But for the BS-1, that memory map is a MAJOR help!

Thanx a bunch!

Geo

Here's your program I did. It is 69% full and missing some of the features that your program had. I can put them in if you want. Please test this one so you can see how it works.

Actually, I can't test it as of yet because I need two switches and a serial output together and I can't do that with the Prop-1 trainer in place.   Likewise without the Prop-1 trainer, I can't monitor the Prop-1's LED outputs.   Thus I am going to have to build a breadboard for this project.

Edit:  Removed bottom part of my response as it was covered in another post.

Geo