Pepper's ghost using prop-1 and FC-1

[megaplay]

Hello all,
I purchased my first prop-1 with the FC-1 add on in Las Vegas this year to do a Pepper's ghost effect in our haunted house.  Everyone at the show was very helpful but needless to say it has been a while and my memory has faded me.  After doing a lot of reading on this board I was seeing if anyone had a code I could use as a starting point.  Basically here is the idea to occur:
1. Actor hits button / step pad which starts the effect.
2. Ambient lighting (We will call light 1) goes up while the other light (We will call light 2) goes down.  This is approximately a 3 second fade.
3. After about 3 seconds in this state with light 2 on, the room returns to ambient lighting, fade of light 2 back to light 1.
4. There is then a 10 second delay before the actor can hit the button again and restart the process.
Thank you for any help.  If you need more detail please let me know, looking for at least some where to start.
Mark Hopkinson.

[JonnyMac]

Mark,

You didn't say how long to fade from channel 2 back to channel 1, so it is presently set to three seconds (3072 milliseconds).  The PAUSE 6000 after the first fade delays three seconds for the fade, holds an additional three for the inter-fade timing.  The PAUSE 13000 after the second fade (from channel 2 back to 1) handles the three-second fade plus 10 seconds of delay.

Be sure to read this post on the ULN: http://www.efx-tek.com/php/smf/index.php?topic=130.0

Also, be sure to read the FC-4 docs carefully: http://www.efx-tek.com/downloads/fc-4_docs.pdf

And here's the program that takes care the requirements you spelled out.

' =========================================================================
'
'   File...... Peppers.BS1
'   Purpose...
'   Author.... Jon Williams, EFX-TEK
'              Copyright (c) 2008 EFX-TEK
'              Some Rights Reserved
'              -- see http://creativecommons.org/licenses/by/3.0/
'   E-mail.... jwilliams@efx-tek.com
'   Started...
'   Updated...
'
'   {$STAMP BS1}
'   {$PBASIC 1.0}
'
' =========================================================================


' -----[ Program Description ]---------------------------------------------


' -----[ Revision History ]------------------------------------------------


' -----[ I/O Definitions ]-------------------------------------------------

SYMBOL  Sio             = 7                     ' SETUP = out; no ULN
SYMBOL  Trigger         = PIN6                  ' SETUP = DN


' -----[ Constants ]-------------------------------------------------------

SYMBOL  IsOn            = 1                     ' for active-high in/out
SYMBOL  IsOff           = 0

SYMBOL  Baud            = OT2400


' -----[ Variables ]-------------------------------------------------------

SYMBOL  timer           = B2


' -----[ Initialization ]--------------------------------------------------

Reset:
  PINS = %00000000                              ' clear all outputs
  DIRS = %00000000                              ' (no local outputs)

  SEROUT Sio, Baud, ("!!!!FC4", %00, "D", %0001)


' -----[ Program Code ]----------------------------------------------------

Main:
  timer = 0                                     ' reset timer

Check_Trigger:
  PAUSE 5                                       ' loop pad
  timer = timer + 5 * Trigger                   ' update timer
  IF timer < 100 THEN Check_Trigger             ' wait for 0.1 sec input

Cross_Fade_1:
  SEROUT Sio, Baud, ("!FC4", %00, "C", 0, 1, 2, 12)
  PAUSE 6000

Cross_Fade_2:
  SEROUT Sio, Baud, ("!FC4", %00, "C", 0, 2, 1, 12)
  PAUSE 13000

  GOTO Main


' -----[ Subroutines ]-----------------------------------------------------


' -------------------------------------------------------------------------


' -------------------------------------------------------------------------


' -----[ User Data ]-------------------------------------------------------

[megaplay]

Thank you so much Jon.  Got it all hooked up tonight and it is perfect.  This was above and beyond what I could ask for.  One question I had for you, in one of your posts you mentioned you save all the programs you write for this board.  Is there somewhere you paste all the old programs or would they be available for download somewhere?  I tend to learn a lot of programing and ideas from clean and completed items and was just curious.  Thanks again.

[JonnyMac]

No, I save them on my drive as well as posting them here.  I doesn't make sense just to stick them out in a folder because they would have no context; by including them in a thread like this new programmers can read the discussion and then see the resulting code.